tests can now be built as part of FSFW

This PR refactores the tests so they are built as part of the FSFW.
This is done by adding Catch2 with the FetchContent directive.

A future implementation might also use a system installation of Catch2
by first checking whether Catch2 can already be found as a package

The custom configuration folder testcfg was moved from the user folder
to the actual unittest folder.

The tests can be built by setting the CMake FSFW_BUILD_UNITTESTS option
to TRUE/ON. They are built with the static library and dropped inside
the build folders fsfw directory.

CMakeLists.txt

@@ -1,5 +1,9 @@
 cmake_minimum_required(VERSION 3.13)
 
+set(FSFW_VERSION 2)
+set(FSFW_SUBVERSION 0)
+set(FSFW_REVISION 0)
+
 option(FSFW_GENERATE_SECTIONS
     "Generate function and data sections. Required to remove unused code" ON
 )
@@ -7,6 +11,11 @@ if(FSFW_GENERATE_SECTIONS)
     option(FSFW_REMOVE_UNUSED_CODE "Remove unused code" ON)
 endif()
 
+option(FSFW_BUILD_UNITTESTS "Build unittest binary in addition to static library" OFF)
+if(FSFW_BUILD_UNITTESTS)
+    option(FSFW_TESTS_GEN_COV "Generate coverage data for unittests" ON)
+endif()
+
 option(FSFW_WARNING_SHADOW_LOCAL_GCC "Enable -Wshadow=local warning in GCC" ON)
 # Options to exclude parts of the FSFW from compilation.
 option(FSFW_ADD_INTERNAL_TESTS "Add internal unit tests" ON)
@@ -26,11 +35,57 @@ option(FSFW_ADD_TMSTORAGE "Compile with tm storage components" OFF)
 option(FSFW_ADD_SGP4_PROPAGATOR "Add SGP4 propagator code" OFF)
 
 set(LIB_FSFW_NAME fsfw)
+set(FSFW_TEST_TGT fsfw-tests)
+
 add_library(${LIB_FSFW_NAME})
+
+if(FSFW_BUILD_UNITTESTS)
+    # Check whether the user has already installed Catch2 first
+    find_package(Catch2 3)
+    # Not installed, so use FetchContent to download and provide Catch2
+    if(NOT Catch2_FOUND)
+        include(FetchContent)
+
+        FetchContent_Declare(
+            Catch2
+            GIT_REPOSITORY https://github.com/catchorg/Catch2.git
+            GIT_TAG        v3.0.0-preview3
+        )
+
+        FetchContent_MakeAvailable(Catch2)
+    endif()
+
+    configure_file(tests/src/fsfw_tests/unit/testcfg/FSFWConfig.h.in tests/FSFWConfig.h)
+    configure_file(tests/src/fsfw_tests/unit/testcfg/TestsConfig.h.in tests/TestsConfig.h)
+    configure_file(tests/src/fsfw_tests/unit/testcfg/OBSWConfig.h.in tests/OBSWConfig.h)
+    add_executable(${FSFW_TEST_TGT})
+
+    if(FSFW_TESTS_GEN_COV)
+        include(FetchContent)
+        FetchContent_Declare(
+            cmake-modules
+            GIT_REPOSITORY https://github.com/bilke/cmake-modules.git
+        )
+        FetchContent_MakeAvailable(cmake-modules)
+        list(APPEND CMAKE_MODULE_PATH ${cmake-modules_SOURCE_DIR})
+        include(CodeCoverage)
+    endif()
+endif()
+
 set(FSFW_CORE_INC_PATH "inc")
 
 set_property(CACHE FSFW_OSAL PROPERTY STRINGS host linux rtems freertos)
 
+# Configure Files
+target_include_directories(${LIB_FSFW_NAME} PRIVATE
+    ${CMAKE_CURRENT_BINARY_DIR}
+)
+target_include_directories(${LIB_FSFW_NAME} INTERFACE
+    ${CMAKE_CURRENT_BINARY_DIR}
+)
+configure_file(src/fsfw/FSFW.h.in FSFW.h)
+configure_file(src/fsfw/FSFWVersion.h.in FSFWVersion.h)
+
 if(NOT CMAKE_CXX_STANDARD)
     set(CMAKE_CXX_STANDARD 11)
     set(CMAKE_CXX_STANDARD_REQUIRED True)
@@ -63,29 +118,29 @@ endif()
 set(FSFW_OSAL_DEFINITION FSFW_OSAL_HOST)
 
 if(FSFW_OSAL MATCHES host)
-    set(OS_FSFW_NAME "Host")
+    set(FSFW_OS_NAME "Host")
     set(FSFW_OSAL_HOST ON)
 elseif(FSFW_OSAL MATCHES linux)
-    set(OS_FSFW_NAME "Linux")
+    set(FSFW_OS_NAME "Linux")
     set(FSFW_OSAL_LINUX ON)
 elseif(FSFW_OSAL MATCHES freertos)
-    set(OS_FSFW_NAME "FreeRTOS")
+    set(FSFW_OS_NAME "FreeRTOS")
     set(FSFW_OSAL_FREERTOS ON)
     target_link_libraries(${LIB_FSFW_NAME} PRIVATE
         ${LIB_OS_NAME}
     )
 elseif(FSFW_OSAL STREQUAL rtems)
-    set(OS_FSFW_NAME "RTEMS")
+    set(FSFW_OS_NAME "RTEMS")
     set(FSFW_OSAL_RTEMS ON)
 else()
     message(WARNING
         "Invalid operating system for FSFW specified! Setting to host.."
     )
-    set(OS_FSFW_NAME "Host")
+    set(FSFW_OS_NAME "Host")
     set(OS_FSFW "host")
 endif()
 
-message(STATUS "Compiling FSFW for the ${OS_FSFW_NAME} operating system.")
+message(STATUS "Compiling FSFW for the ${FSFW_OS_NAME} operating system.")
 
 add_subdirectory(src)
 add_subdirectory(tests)
@@ -94,6 +149,66 @@ if(FSFW_ADD_HAL)
 endif()
 add_subdirectory(contrib)
 
+if(FSFW_BUILD_UNITTESTS)
+    if(FSFW_TESTS_GEN_COV)
+        if(CMAKE_COMPILER_IS_GNUCXX)
+            include(CodeCoverage)
+
+            # Remove quotes.
+            separate_arguments(COVERAGE_COMPILER_FLAGS
+                NATIVE_COMMAND "${COVERAGE_COMPILER_FLAGS}"
+            )
+
+            # Add compile options manually, we don't want coverage for Catch2
+            target_compile_options(${FSFW_TEST_TGT} PRIVATE
+                "${COVERAGE_COMPILER_FLAGS}"
+            )
+            target_compile_options(${LIB_FSFW_NAME} PRIVATE
+                "${COVERAGE_COMPILER_FLAGS}"
+            )
+
+            # Exclude directories here
+            if(WIN32)
+                set(GCOVR_ADDITIONAL_ARGS
+                    "--exclude-throw-branches"
+                    "--exclude-unreachable-branches"
+                )
+                set(COVERAGE_EXCLUDES
+                    "/c/msys64/mingw64/*"
+                )
+            elseif(UNIX)
+                set(COVERAGE_EXCLUDES
+                    "/usr/include/*" "/usr/bin/*" "Catch2/*"
+                )
+            endif()
+
+            target_link_options(${FSFW_TEST_TGT} PRIVATE
+                -fprofile-arcs
+                -ftest-coverage
+            )
+            target_link_options(${LIB_FSFW_NAME} PRIVATE
+                -fprofile-arcs
+                -ftest-coverage
+            )
+
+            if(WIN32)
+                setup_target_for_coverage_gcovr_html(
+                    NAME ${FSFW_TEST_TGT}_coverage
+                    EXECUTABLE ${FSFW_TEST_TGT}
+                    DEPENDENCIES ${FSFW_TEST_TGT}
+                )
+            else()
+                setup_target_for_coverage_lcov(
+                    NAME ${FSFW_TEST_TGT}_coverage
+                    EXECUTABLE ${FSFW_TEST_TGT}
+                    DEPENDENCIES ${FSFW_TEST_TGT}
+                )
+            endif()
+        endif()
+    endif()
+    target_link_libraries(${FSFW_TEST_TGT} PRIVATE Catch2::Catch2 ${LIB_FSFW_NAME})
+endif()
+
 # The project CMakeLists file has to set the FSFW_CONFIG_PATH and add it.
 # If this is not given, we include the default configuration and emit a warning.
 if(NOT FSFW_CONFIG_PATH)
@@ -186,4 +301,4 @@ target_compile_options(${LIB_FSFW_NAME} PRIVATE
 
 target_link_libraries(${LIB_FSFW_NAME} PRIVATE
     ${FSFW_ADDITIONAL_LINK_LIBS}
-)
+)