git describe support finished

2022-04-22 14:09:08 +02:00
parent d6532f8181
commit a416ca406b
16 changed files with 491 additions and 116 deletions
--- a/cmake/GetGitRevisionDescription.cmake
+++ b/cmake/GetGitRevisionDescription.cmake
@ -0,0 +1,284 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_describe_working_tree(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the working tree (--dirty option),
+# and adjusting the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+#  git_local_changes(<var>)
+#
+# Returns either "CLEAN" or "DIRTY" with respect to uncommitted changes.
+# Uses the return code of "git diff-index --quiet HEAD --".
+# Does not regard untracked files.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2020 Ryan Pavlik <ryan.pavlik@gmail.com> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+#
+# Copyright 2009-2013, Iowa State University.
+# Copyright 2013-2020, Ryan Pavlik
+# Copyright 2013-2020, Contributors
+# SPDX-License-Identifier: BSL-1.0
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+    return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+# Function _git_find_closest_git_dir finds the next closest .git directory
+# that is part of any directory in the path defined by _start_dir.
+# The result is returned in the parent scope variable whose name is passed
+# as variable _git_dir_var. If no .git directory can be found, the
+# function returns an empty string via _git_dir_var.
+#
+# Example: Given a path C:/bla/foo/bar and assuming C:/bla/.git exists and
+# neither foo nor bar contain a file/directory .git. This wil return
+# C:/bla/.git
+#
+function(_git_find_closest_git_dir _start_dir _git_dir_var)
+    set(cur_dir "${_start_dir}")
+    set(git_dir "${_start_dir}/.git")
+    while(NOT EXISTS "${git_dir}")
+        # .git dir not found, search parent directories
+        set(git_previous_parent "${cur_dir}")
+        get_filename_component(cur_dir "${cur_dir}" DIRECTORY)
+        if(cur_dir STREQUAL git_previous_parent)
+            # We have reached the root directory, we are not in git
+            set(${_git_dir_var}
+                ""
+                PARENT_SCOPE)
+            return()
+        endif()
+        set(git_dir "${cur_dir}/.git")
+    endwhile()
+    set(${_git_dir_var}
+        "${git_dir}"
+        PARENT_SCOPE)
+endfunction()
+
+function(get_git_head_revision _refspecvar _hashvar)
+    _git_find_closest_git_dir("${CMAKE_CURRENT_SOURCE_DIR}" GIT_DIR)
+
+    if("${ARGN}" STREQUAL "ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR")
+        set(ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR TRUE)
+    else()
+        set(ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR FALSE)
+    endif()
+    if(NOT "${GIT_DIR}" STREQUAL "")
+        file(RELATIVE_PATH _relative_to_source_dir "${CMAKE_SOURCE_DIR}"
+             "${GIT_DIR}")
+        if("${_relative_to_source_dir}" MATCHES "[.][.]" AND NOT ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR)
+            # We've gone above the CMake root dir.
+            set(GIT_DIR "")
+        endif()
+    endif()
+    if("${GIT_DIR}" STREQUAL "")
+        set(${_refspecvar}
+            "GITDIR-NOTFOUND"
+            PARENT_SCOPE)
+        set(${_hashvar}
+            "GITDIR-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+
+    # Check if the current source dir is a git submodule or a worktree.
+    # In both cases .git is a file instead of a directory.
+    #
+    if(NOT IS_DIRECTORY ${GIT_DIR})
+        # The following git command will return a non empty string that
+        # points to the super project working tree if the current
+        # source dir is inside a git submodule.
+        # Otherwise the command will return an empty string.
+        #
+        execute_process(
+            COMMAND "${GIT_EXECUTABLE}" rev-parse
+                    --show-superproject-working-tree
+            WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+            OUTPUT_VARIABLE out
+            ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+        if(NOT "${out}" STREQUAL "")
+            # If out is empty, GIT_DIR/CMAKE_CURRENT_SOURCE_DIR is in a submodule
+            file(READ ${GIT_DIR} submodule)
+            string(REGEX REPLACE "gitdir: (.*)$" "\\1" GIT_DIR_RELATIVE
+                                 ${submodule})
+            string(STRIP ${GIT_DIR_RELATIVE} GIT_DIR_RELATIVE)
+            get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+            get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE}
+                                   ABSOLUTE)
+            set(HEAD_SOURCE_FILE "${GIT_DIR}/HEAD")
+        else()
+            # GIT_DIR/CMAKE_CURRENT_SOURCE_DIR is in a worktree
+            file(READ ${GIT_DIR} worktree_ref)
+            # The .git directory contains a path to the worktree information directory
+            # inside the parent git repo of the worktree.
+            #
+            string(REGEX REPLACE "gitdir: (.*)$" "\\1" git_worktree_dir
+                                 ${worktree_ref})
+            string(STRIP ${git_worktree_dir} git_worktree_dir)
+            _git_find_closest_git_dir("${git_worktree_dir}" GIT_DIR)
+            set(HEAD_SOURCE_FILE "${git_worktree_dir}/HEAD")
+        endif()
+    else()
+        set(HEAD_SOURCE_FILE "${GIT_DIR}/HEAD")
+    endif()
+    set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+    if(NOT EXISTS "${GIT_DATA}")
+        file(MAKE_DIRECTORY "${GIT_DATA}")
+    endif()
+
+    if(NOT EXISTS "${HEAD_SOURCE_FILE}")
+        return()
+    endif()
+    set(HEAD_FILE "${GIT_DATA}/HEAD")
+    configure_file("${HEAD_SOURCE_FILE}" "${HEAD_FILE}" COPYONLY)
+
+    configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+                   "${GIT_DATA}/grabRef.cmake" @ONLY)
+    include("${GIT_DATA}/grabRef.cmake")
+
+    set(${_refspecvar}
+        "${HEAD_REF}"
+        PARENT_SCOPE)
+    set(${_hashvar}
+        "${HEAD_HASH}"
+        PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+    if(NOT GIT_FOUND)
+        find_package(Git QUIET)
+    endif()
+    get_git_head_revision(refspec hash)
+    if(NOT GIT_FOUND)
+        set(${_var}
+            "GIT-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+    if(NOT hash)
+        set(${_var}
+            "HEAD-HASH-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+
+    # TODO sanitize
+    #if((${ARGN}" MATCHES "&&") OR
+    #   (ARGN MATCHES "||") OR
+    #   (ARGN MATCHES "\\;"))
+    #   message("Please report the following error to the project!")
+    #   message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+    #endif()
+
+    #message(STATUS "Arguments to execute_process: ${ARGN}")
+
+    execute_process(
+        COMMAND "${GIT_EXECUTABLE}" describe --tags --always ${hash} ${ARGN}
+        WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+        RESULT_VARIABLE res
+        OUTPUT_VARIABLE out
+        ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if(NOT res EQUAL 0)
+        set(out "${out}-${res}-NOTFOUND")
+    endif()
+
+    set(${_var}
+        "${out}"
+        PARENT_SCOPE)
+endfunction()
+
+function(git_describe_working_tree _var)
+    if(NOT GIT_FOUND)
+        find_package(Git QUIET)
+    endif()
+    if(NOT GIT_FOUND)
+        set(${_var}
+            "GIT-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+
+    execute_process(
+        COMMAND "${GIT_EXECUTABLE}" describe --dirty ${ARGN}
+        WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+        RESULT_VARIABLE res
+        OUTPUT_VARIABLE out
+        ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if(NOT res EQUAL 0)
+        set(out "${out}-${res}-NOTFOUND")
+    endif()
+
+    set(${_var}
+        "${out}"
+        PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+    git_describe(out --exact-match ${ARGN})
+    set(${_var}
+        "${out}"
+        PARENT_SCOPE)
+endfunction()
+
+function(git_local_changes _var)
+    if(NOT GIT_FOUND)
+        find_package(Git QUIET)
+    endif()
+    get_git_head_revision(refspec hash)
+    if(NOT GIT_FOUND)
+        set(${_var}
+            "GIT-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+    if(NOT hash)
+        set(${_var}
+            "HEAD-HASH-NOTFOUND"
+            PARENT_SCOPE)
+        return()
+    endif()
+
+    execute_process(
+        COMMAND "${GIT_EXECUTABLE}" diff-index --quiet HEAD --
+        WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+        RESULT_VARIABLE res
+        OUTPUT_VARIABLE out
+        ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if(res EQUAL 0)
+        set(${_var}
+            "CLEAN"
+            PARENT_SCOPE)
+    else()
+        set(${_var}
+            "DIRTY"
+            PARENT_SCOPE)
+    endif()
+endfunction()
--- a/cmake/GetGitRevisionDescription.cmake.in
+++ b/cmake/GetGitRevisionDescription.cmake.in
@ -0,0 +1,43 @@
+#
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright 2009-2012, Iowa State University
+# Copyright 2011-2015, Contributors
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+# SPDX-License-Identifier: BSL-1.0
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+    # named branch
+    string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+    if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+        configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+    else()
+        configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs" COPYONLY)
+        file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
+        if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
+            set(HEAD_HASH "${CMAKE_MATCH_1}")
+        endif()
+    endif()
+else()
+    # detached HEAD
+    configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+    file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+    string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()
--- a/cmake/HardwareOsPostConfig.cmake
+++ b/cmake/HardwareOsPostConfig.cmake
@ -1,16 +1,5 @@
 function(post_source_hw_os_config)

-if(LINK_LWIP)
-	message(STATUS "Linking against ${LIB_LWIP_NAME} lwIP library")
-	if(LIB_LWIP_NAME)
-		target_link_libraries(${OBSW_NAME} PUBLIC 
-			${LIB_LWIP_NAME}
-		)
-	else()
-		message(WARNING "lwIP library name not set!")
-	endif()
-endif()
-
 if(LINKER_SCRIPT)
 	add_link_options(
 		-T${LINKER_SCRIPT}
--- a/cmake/HardwareOsPreConfig.cmake
+++ b/cmake/HardwareOsPreConfig.cmake
@ -1,74 +0,0 @@
-function(pre_source_hw_os_config)
-
-# FreeRTOS
-if(FSFW_OSAL MATCHES freertos)
-	message(FATAL_ERROR "No FreeRTOS support implemented yet.")
-# RTEMS
-elseif(FSFW_OSAL STREQUAL rtems)
-	add_definitions(-DRTEMS)
-	message(FATAL_ERROR "No RTEMS support implemented yet.")
-elseif(FSFW_OSAL STREQUAL linux)
-	add_definitions(-DUNIX -DLINUX)	
-	find_package(Threads REQUIRED)
-# Hosted
-else()
-	set(BSP_PATH "bsp_hosted")
-	if(WIN32)
-    	add_definitions(-DWIN32)
-	elseif(UNIX)
-		find_package(Threads REQUIRED)
-		add_definitions(-DUNIX -DLINUX)	
-	endif()
-endif()
-
-# Cross-compile information
-if(CMAKE_CROSSCOMPILING)
-	# set(CMAKE_VERBOSE TRUE)
-
-	message(STATUS "Cross-compiling for ${TGT_BSP} target")
-	message(STATUS "Cross-compile gcc: ${CMAKE_C_COMPILER}")
-	message(STATUS "Cross-compile g++: ${CMAKE_CXX_COMPILER}")
-	
-	if(CMAKE_VERBOSE)
-		message(STATUS "Cross-compile linker: ${CMAKE_LINKER}")
-		message(STATUS "Cross-compile size utility: ${CMAKE_SIZE}")
-		message(STATUS "Cross-compile objcopy utility: ${CMAKE_OBJCOPY}")
-		message(STATUS "Cross-compile ranlib utility: ${CMAKE_RANLIB}")
-		message(STATUS "Cross-compile ar utility: ${CMAKE_AR}")
-		message(STATUS "Cross-compile nm utility: ${CMAKE_NM}")
-		message(STATUS "Cross-compile strip utility: ${CMAKE_STRIP}")
-		message(STATUS 
-			"Cross-compile assembler: ${CMAKE_ASM_COMPILER} "
-			"-x assembler-with-cpp"
-		)
-		message(STATUS "ABI flags: ${ABI_FLAGS}")
-		message(STATUS "Custom linker script: ${LINKER_SCRIPT}")
-	endif()
-	
-	set_property(CACHE TGT_BSP 
-		PROPERTY STRINGS  
-		"arm/q7s" "arm/raspberrypi" "arm/egse"
-	)
-endif()
-	
-
-if(TGT_BSP)
-	if (TGT_BSP MATCHES "arm/raspberrypi" OR TGT_BSP MATCHES "arm/beagleboneblack")
-		set(BSP_PATH "bsp_linux_board")
-	elseif(TGT_BSP MATCHES "arm/q7s")
-		set(BSP_PATH "bsp_q7s")
-  elseif(TGT_BSP MATCHES "arm/egse")
-    set(BSP_PATH "bsp_egse")
-  elseif(TGT_BSP MATCHES "arm/te0720-1cfa")
-    set(BSP_PATH "bsp_te0720_1cfa")
-	else() 
-		message(WARNING "CMake not configured for this target!")
-		message(FATAL_ERROR "Target: ${TGT_BSP}!")
-	endif()
-else()
-	set(BSP_PATH "bsp_hosted")
-endif()
-		
-set(BSP_PATH ${BSP_PATH} PARENT_SCOPE)
-
-endfunction()
--- a/cmake/PreProjectConfig.cmake
+++ b/cmake/PreProjectConfig.cmake
@ -1,3 +1,78 @@
+function(pre_source_hw_os_config)
+
+# FreeRTOS
+if(FSFW_OSAL MATCHES freertos)
+    message(FATAL_ERROR "No FreeRTOS support implemented yet.")
+# RTEMS
+elseif(FSFW_OSAL STREQUAL rtems)
+    add_definitions(-DRTEMS)
+    message(FATAL_ERROR "No RTEMS support implemented yet.")
+elseif(FSFW_OSAL STREQUAL linux)
+    add_definitions(-DUNIX -DLINUX) 
+    find_package(Threads REQUIRED)
+# Hosted
+else()
+    set(BSP_PATH "bsp_hosted")
+    if(WIN32)
+        add_definitions(-DWIN32)
+    elseif(UNIX)
+        find_package(Threads REQUIRED)
+        add_definitions(-DUNIX -DLINUX) 
+    endif()
+endif()
+
+# Cross-compile information
+if(CMAKE_CROSSCOMPILING)
+    # set(CMAKE_VERBOSE TRUE)
+
+    message(STATUS "Cross-compiling for ${TGT_BSP} target")
+    message(STATUS "Cross-compile gcc: ${CMAKE_C_COMPILER}")
+    message(STATUS "Cross-compile g++: ${CMAKE_CXX_COMPILER}")
+    
+    if(CMAKE_VERBOSE)
+        message(STATUS "Cross-compile linker: ${CMAKE_LINKER}")
+        message(STATUS "Cross-compile size utility: ${CMAKE_SIZE}")
+        message(STATUS "Cross-compile objcopy utility: ${CMAKE_OBJCOPY}")
+        message(STATUS "Cross-compile ranlib utility: ${CMAKE_RANLIB}")
+        message(STATUS "Cross-compile ar utility: ${CMAKE_AR}")
+        message(STATUS "Cross-compile nm utility: ${CMAKE_NM}")
+        message(STATUS "Cross-compile strip utility: ${CMAKE_STRIP}")
+        message(STATUS 
+            "Cross-compile assembler: ${CMAKE_ASM_COMPILER} "
+            "-x assembler-with-cpp"
+        )
+        message(STATUS "ABI flags: ${ABI_FLAGS}")
+        message(STATUS "Custom linker script: ${LINKER_SCRIPT}")
+    endif()
+    
+    set_property(CACHE TGT_BSP 
+        PROPERTY STRINGS  
+        "arm/q7s" "arm/raspberrypi" "arm/egse"
+    )
+endif()
+    
+
+if(TGT_BSP)
+    if (TGT_BSP MATCHES "arm/raspberrypi" OR TGT_BSP MATCHES "arm/beagleboneblack")
+        set(BSP_PATH "bsp_linux_board")
+    elseif(TGT_BSP MATCHES "arm/q7s")
+        set(BSP_PATH "bsp_q7s")
+  elseif(TGT_BSP MATCHES "arm/egse")
+    set(BSP_PATH "bsp_egse")
+  elseif(TGT_BSP MATCHES "arm/te0720-1cfa")
+    set(BSP_PATH "bsp_te0720_1cfa")
+    else() 
+        message(WARNING "CMake not configured for this target!")
+        message(FATAL_ERROR "Target: ${TGT_BSP}!")
+    endif()
+else()
+    set(BSP_PATH "bsp_hosted")
+endif()
+        
+set(BSP_PATH ${BSP_PATH} PARENT_SCOPE)
+
+endfunction()
+
 function(pre_project_config)

 # Basic input sanitization
--- a/cmake/helpers.cmake
+++ b/cmake/helpers.cmake
@ -0,0 +1,28 @@
+# Determines the git version with git describe and returns it by setting
+# the GIT_INFO list in the parent scope. The list has the following entries
+# 1. Full version string
+# 2. Major version
+# 3. Minor version
+# 4. Revision
+# 5. git SHA hash and commits since tag
+function(determine_version_with_git)
+    include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/GetGitRevisionDescription.cmake)
+    git_describe(VERSION ${ARGN})
+    string(FIND ${VERSION} "." VALID_VERSION)
+    if(VALID_VERSION EQUAL -1)
+        message(WARNING "Version string ${VERSION} retrieved with git describe is invalid")
+        return()
+    endif()
+    # Parse the version information into pieces.
+    string(REGEX REPLACE "^v([0-9]+)\\..*" "\\1" _VERSION_MAJOR "${VERSION}")
+    string(REGEX REPLACE "^v[0-9]+\\.([0-9]+).*" "\\1" _VERSION_MINOR "${VERSION}")
+    string(REGEX REPLACE "^v[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" _VERSION_PATCH "${VERSION}")
+    string(REGEX REPLACE "^v[0-9]+\\.[0-9]+\\.[0-9]+-(.*)" "\\1" VERSION_SHA1 "${VERSION}")
+    set(GIT_INFO ${VERSION})
+    list(APPEND GIT_INFO ${_VERSION_MAJOR})
+    list(APPEND GIT_INFO ${_VERSION_MINOR})
+    list(APPEND GIT_INFO ${_VERSION_PATCH})
+    list(APPEND GIT_INFO ${VERSION_SHA1})
+    set(GIT_INFO ${GIT_INFO} PARENT_SCOPE)
+    message(STATUS "eive | Set git version info into GIT_INFO from the git tag ${VERSION}")
+endfunction()