eive-obsw/CMakeLists.txt

################################################################################
# CMake support for the EIVE OBSW
# 
# Developed in an effort to replace Make with a modern build system.
# 
# Author: R. Mueller
################################################################################

################################################################################
# Pre-Project preparation
################################################################################
cmake_minimum_required(VERSION 3.13)

# set(CMAKE_VERBOSE TRUE)

set(CMAKE_SCRIPT_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")

option(ADD_ETL_LIB "Add ETL library" ON)
if(NOT OS_FSFW)
	set(OS_FSFW host CACHE STRING "OS for the FSFW.")
endif()

# Perform steps like loading toolchain files where applicable.
include(${CMAKE_SCRIPT_PATH}/PreProjectConfig.cmake)
pre_project_config()

# Project Name
project(eive_obsw ASM C CXX)

################################################################################
# Pre-Sources preparation
################################################################################

# Specify the C++ standard
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED True)

# Set names and variables
set(TARGET_NAME ${CMAKE_PROJECT_NAME}) 
set(LIB_FSFW_NAME fsfw)
set(LIB_ETL_NAME etl)
set(LIB_CSP_NAME libcsp)
set(LIB_FSFW_HAL_NAME fsfw_hal)
set(LIB_LWGPS_NAME lwgps)
set(THIRD_PARTY_FOLDER thirdparty)

# Set path names
set(FSFW_PATH fsfw)
set(MISSION_PATH mission)
set(TEST_PATH test/testtasks)
set(LINUX_PATH linux)
set(COMMON_PATH common)

set(FSFW_HAL_LIB_PATH fsfw_hal)
set(CSP_LIB_PATH ${THIRD_PARTY_FOLDER}/libcsp)
set(ETL_LIB_PATH ${THIRD_PARTY_FOLDER}/etl)
set(LWGPS_LIB_PATH ${THIRD_PARTY_FOLDER}/lwgps)

set(FSFW_WARNING_SHADOW_LOCAL_GCC OFF)
set(ADD_LINUX_FILES FALSE)

# Analyse different OS and architecture/target options, determine BSP_PATH,
# display information about compiler etc.
include (${CMAKE_SCRIPT_PATH}/HardwareOsPreConfig.cmake)
pre_source_hw_os_config()

if(TGT_BSP)
    if(${TGT_BSP} MATCHES "arm/q7s" OR ${TGT_BSP} MATCHES "arm/raspberrypi")
        set(ROOT_CONFIG_FOLDER TRUE)
        set(FSFW_CONFIG_PATH "fsfwconfig")
        set(ADD_LINUX_FILES TRUE)
        set(ADD_CSP_LIB TRUE)
        set(FSFW_HAL_ADD_LINUX ON)
    endif()
   
    if(${TGT_BSP} MATCHES "arm/raspberrypi") 
        add_definitions(-DRASPBERRY_PI)
        set(FSFW_HAL_ADD_RASPBERRY_PI ON)
    endif()
    
    if(${TGT_BSP} MATCHES "arm/q7s")
        add_definitions(-DXIPHOS_Q7S)
    endif()
else()
    # Required by FSFW library
    set(FSFW_CONFIG_PATH "${BSP_PATH}/fsfwconfig")
endif()
# Set for lwgps library
set(LWGPS_CONFIG_PATH "${COMMON_PATH}/config")

################################################################################
# Executable and Sources
################################################################################

# Add executable
add_executable(${TARGET_NAME})

# Add subdirectories
if(ROOT_CONFIG_FOLDER)
    add_subdirectory(${FSFW_CONFIG_PATH})
endif()

if(ADD_CSP_LIB)
    add_subdirectory(${CSP_LIB_PATH})
endif()

if(ADD_ETL_LIB)
    add_subdirectory(${ETL_LIB_PATH})
endif()

if(ADD_LINUX_FILES)
    add_subdirectory(${LINUX_PATH})
endif()

add_subdirectory(${LWGPS_LIB_PATH})
add_subdirectory(${BSP_PATH})
add_subdirectory(${FSFW_PATH})
add_subdirectory(${MISSION_PATH})
add_subdirectory(${TEST_PATH})
add_subdirectory(${FSFW_HAL_LIB_PATH})
add_subdirectory(${COMMON_PATH})

################################################################################
# Post-Sources preparation
################################################################################

set_property(CACHE OS_FSFW PROPERTY STRINGS host linux)

# Add libraries for all sources.
target_link_libraries(${TARGET_NAME} PRIVATE
	${LIB_FSFW_NAME} 
	${LIB_OS_NAME} 
	${LIB_LWGPS_NAME}
	${LIB_FSFW_HAL_NAME}
)

if(ADD_ETL_LIB)
    target_link_libraries(${TARGET_NAME} PRIVATE
        ${LIB_ETL_NAME}
    )
endif()

if(ADD_CSP_LIB)
	target_link_libraries(${TARGET_NAME} PRIVATE
		${LIB_CSP_NAME}
	)
endif()

# Add include paths for all sources.
target_include_directories(${TARGET_NAME} PRIVATE
	${CMAKE_CURRENT_SOURCE_DIR}
	${FSFW_CONFIG_PATH}
)	


if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
	set(WARNING_FLAGS
		-Wall
		-Wextra
		-Wimplicit-fallthrough=1
		-Wno-unused-parameter
		-Wno-psabi
	)
	
	# Remove unused sections.
	target_compile_options(${TARGET_NAME} PRIVATE
		"-ffunction-sections"
		"-fdata-sections"
	)

	# Removed unused sections.
	target_link_options(${TARGET_NAME} PRIVATE
		"-Wl,--gc-sections"
	)
	
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
	set(COMPILER_FLAGS "/permissive-")
endif()

if(CMAKE_VERBOSE)
	message(STATUS "Warning flags: ${WARNING_FLAGS}")
endif()
		 

# Compile options for all sources.
target_compile_options(${TARGET_NAME} PRIVATE
	${WARNING_FLAGS}
)

if(${CMAKE_CROSSCOMPILING})
	include (${CMAKE_SCRIPT_PATH}/HardwareOsPostConfig.cmake)
	post_source_hw_os_config()
endif()

if(NOT CMAKE_SIZE)
	set(CMAKE_SIZE size)
	if(WIN32)
		set(FILE_SUFFIX ".exe")
	endif()
endif()

if(TGT_BSP)
	set(TARGET_STRING "Target BSP: ${TGT_BSP}")
else()
	set(TARGET_STRING "Target BSP: Hosted")
endif()

string(CONCAT POST_BUILD_COMMENT
    "Build directory: ${CMAKE_BINARY_DIR}\n"
    "Target OSAL: ${OS_FSFW}\n"
    "Target Build Type: ${CMAKE_BUILD_TYPE}\n"
    "${TARGET_STRING}"
)

add_custom_command(
   TARGET ${TARGET_NAME}
   POST_BUILD
   COMMAND ${CMAKE_SIZE} ${TARGET_NAME}${FILE_SUFFIX}
   COMMENT ${POST_BUILD_COMMENT}
)

include (${CMAKE_SCRIPT_PATH}/BuildType.cmake)
set_build_type()